Инвентаризация компьютеров программой SIV (System Information Viewer)

---

Точная информация о составе системного блока нужна в самых разных ситуациях — при установке драйверов, при планировании «апгрейда», при проведении инвентаризации компьютеров в организации.

Лучшая программа для сбора информации о компьютере, на мой взгляд — SIV (System Information Viewer). Такой выбор сделан после тестирования множества похожих программ: «Everest», «Sandra», «Fresh Diagnose», «SIW», «HWiNFO32», «msinfo32.exe», «psinfo.exe», «mvPCinfo» и др.

Преимущества данной программы:

• Распространяется бесплатно.
• Регулярно обновляется и опознает современное оборудование.
• Не требует установки, может запускаться со съемного носителя.
• При запуске из командной строки создает отчет без показа каких-либо сообщений.
• Можно настроить содержание отчета, выводить только нужные секции.
• Текстовый формат отчетов удобен для быстрого просмотра на любом компьютере.

Также возможен запуск программы с сетевого ресурса и сбор информации с удаленного компьютера, но для этого необходимы некоторые дополнения, о которых рассказано ниже.

Настройка отчета и запуск со съемного диска

Чтобы не загромождать отчет лишней информацией и не тратить время на ее сбор, следует формировать отчет из командной строки, указав нужные параметры. Список параметров командной строки — см. кнопку «About» в главном окне программы.

По умолчанию отчеты сохраняются в текущий каталог с именем SIV_%COMPUTERNAME%.txt. Для дальнейшего использования удобнее сохранять отчет в отдельный подкаталог и к имени файла добавить дату создания. Все это также можно настроить в командной строке.

Нужные секции указываются после ключа -save= в квадратных скобках, одна за одной. Чтобы узнать название и назначение каждой из них достаточно создать и изучить полный отчет.

Пример командного файла _local.cmd (подчерк нужен, чтобы быстро найти файл среди других) для запуска со съемного диска:

@rem Сбор информации о компьютере программой SIV (System Information Viewer)
@rem Запуск со съемного носителя, сохранение отчета в подкаталог Report
@rem
@rem выполнить программу, отчет будет создан в текущем каталоге
@title SIV (System Information Viewer)
siv -save=[overview][system][monitors][volumes][drives][mapping][partitions][machine][usb-bus][pci-bus][modems][adapters][interface][devices]=Report\%COMPUTERNAME%_%DATE%.txt

Если указанный каталог для сохранения отчетов не существует, программа сама его создавать не станет. Отчет будет записан в каталог %TEMP%. То же самое произойдет, если у программы недостаточно прав на запись в указанный каталог.

Итак, порядок действий:

• Распаковать архив с последней версией программы в отдельный каталог на съемном диске.
• Поместить _local.cmd в этот каталог.
• Там же создать подкаталог Report для отчетов.
• Выполнить _local.cmd и убедиться, что в подкаталоге Report появился отчет.

Запуск с сетевого ресурса

В локальной сети удобно выложить программу на сервер и при необходимости запускать оттуда с любого компьютера.

Прежде всего надо создать сетевой ресурс, в нем создать подкаталог Report и дать права всем пользователям на запись (но не на изменение/удаление) отчетов в нем.

В созданный каталог распаковать архив с последней версией программы.

В тот же каталог поместить командный файл _network.cmd такого содержания:

@rem Сбор информации о компьютере программой SIV (System Information Viewer)
@rem Запускать можно по сети - вручную или через logon-скрипт
@rem
@rem проверить свободную букву и подключить диск
cd /D U:
if not errorlevel 1 goto Exit
net use U: \\SRV\Invent\SIV
@rem выполнить программу, отчет будет создан в подкаталоге Report
cd /D U:
siv -save=[overview][system][monitors][volumes][drives][mapping][partitions][machine][usb-bus][pci-bus][modems][adapters][interface][devices]=Report\%COMPUTERNAME%_%DATE%.txt
@rem отключить диск
cd /D %TEMP%
net use U: /delete
:Exit

В данном примере ресурс имеет адрес \\SRV\Invent\SIV, не забудьте подставить свое значение!

Чтобы проверить работоспособность, следует открыть упомянутый сетевой ресурс и запустить на выполнение _network.cmd. Появится консольное окно, подержится несколько секунд и потом закроется, в подкаталоге Report появится новый файл отчета.

Сбор информации с удаленного компьютера

Один из способов запуска командного файла на удаленном компьютере является утилита «PsExec». Достаточно загрузить "Комплект программ PsTools" (это ZIP-архив размером примерно 1 Мб), извлечь файл psexec.exe и поместить рядом с siv.exe.

Программа консольная, но работу с ней можно упростить. В том же каталоге создать командный файл _remote.cmd такого содержания:

@echo off
rem Сбор информации о компьютере программой SIV (System Information Viewer)
rem Запуск на удаленном компьютере через psexec от имени текущего пользователя
rem
title Remote console
rem спросить имя компьютера
set /P COMP=Computer name or IP-address?
rem команды для выполнения на удаленной машине в отдельном файле .cmd
set EXEC=\\SRV\Invent\SIV\_network.cmd
rem будет запрошен пароль для текущей учетной записи
psexec \\%COMP% -U %USERDOMAIN%\%USERNAME% "%EXEC%"
rem не закрывать консоль, чтобы увидеть результаты
pause

В данном примере ресурс имеет адрес \\SRV\Invent\SIV, не забудьте подставить свое значение!

Теперь для получения отчета с удаленного компьютера достаточно запустить _remote.cmd, ввести имя компьютера, затем — пароль текущей учетной записи. Подразумевается, что запускать _remote.cmd будет администратор, имеющий достаточно привилегий. Чтобы использовать отдельную учетную запись, надо изменить значение параметра -U %USERDOMAIN%\%USERNAME%.

---